Grabbing a Webpage Greater than 32k using UTL_HTTP

The UTL_HTTP package in Oracle allows PL/SQL to grab a webpage and save it into an Oracle variable. The trouble is, it returns a Varchar2 and this can be up to 32k. The solution is to use the DBMS_LOB package to write to a CLOB. A loop gets the 32k chunks and appends them to the CLOB. Straightforward enough but it takes some time to get it all working. Here's the code:

CREATE OR REPLACE PROCEDURE load_html_from_url (p_url  IN  VARCHAR2, p_html out clob) AS
 l_http_request   UTL_HTTP.req;
 l_http_response  UTL_HTTP.resp;
 l_clob           CLOB;
 l_text           VARCHAR2(32767);
BEGIN
 -- Initialize the CLOB.
 DBMS_LOB.createtemporary(l_clob, FALSE);

 -- Make a HTTP request and get the response.
 l_http_request  := UTL_HTTP.begin_request(p_url);
 l_http_response := UTL_HTTP.get_response(l_http_request);

 -- Copy the response into the CLOB.
 BEGIN
   LOOP
     UTL_HTTP.read_text(l_http_response, l_text, 32767);
     DBMS_LOB.writeappend (l_clob, LENGTH(l_text), l_text);
   END LOOP;
 EXCEPTION
   WHEN UTL_HTTP.end_of_body THEN
     UTL_HTTP.end_response(l_http_response);
 END;

 p_html:= l_clob;
EXCEPTION
 WHEN OTHERS THEN
   UTL_HTTP.end_response(l_http_response);
   -- Relase the resources associated with the temporary LOB.
   DBMS_LOB.freetemporary(l_clob);
   RAISE;
END load_html_from_url;

Note: if you want to use HTTP POST instead of GET, you will need to create your request differently. Use

l_http_request := UTL_HTTP.begin_request(v_url, 'POST', 'HTTP/1.1');
utl_http.write_text(l_http_request, v_message);

It may also be necessary to specify the content length like so:

utl_http.set_header(l_http_request, 'Content-Length', length(v_message));